Anyone using SNL to build channel lists for sat or cable? If yes, how?

thanks

Lyndel:
I am just getting started with SNL, and have seen messages mentioning the jumpstart package. Can you send a copy to [email protected]?
Thanks, Larry

Yes,

I'm using the 21-pixel high buttons. My list does have custom graphics but the default ones will work as well.

The 'Levels' property is set for 'Artist->Disc' where Artist is the category 'News', 'Movies', etc... and Disc is the actual channel.


The SNL player is configured as follows:

Gen Instruments cable box with 200ms delay between identical buttons.

Keypad 0-9 are used. Padding is set for 3 digits so that 'Enter/OK' does not have to be pressed.

No Before Disc/Track or After Disc/Track entries are required.

You've got mail.

I've checked the postings and the file list to see if I could get this without posting, but could someone send me the JumpStart documentation? Thanks in advance!

You've got mail

Hi lyndel,
I am starting with SNL, Could you send a copy of the jumpstart package to [email protected]
Thanks in advance

Done

Hi lyndel, I am starting with SNL, Could you send a copy of the jumpstart package to [email protected]

*** Attention ***

This thread is getting extremely long and difficult to read with so many Jump-Start requests.

As a result, I will no longer send the SNL Jump Start if you post to this thread. The only way to receive it is to email me directly.

For the benefit of others, this thread is a support/problem thread and needs to be fairly concise as to problem and solution.

Thanks for your compliance.

I have a question.

I have two LISTS: ARTIST and TITLE.I'd like to be able to jump between them. For example, on the ARTIST list I specified a JUMP to the TITLE Alphabet panel. This gave me the error message: "In List 'Artist': hard button left has non-existent jump panel. Is there a way around this?

Although very powerful, links between lists are not currently supported and were never supported even on the original B&W version by Leo.

In fact, the only way you were able to add the Hard Button definition was to specify a previous 'output' CF as your input CCF as your output CCF contains the device named 'Title'.

Please note that you can also achieve this by a simple manual edit following SNL execution.

Sorry 'bout that.

Lyndel

Bumpety Bump, Bump!

Many folks have been sending me CCFs that have been edited with Tonto and are encountering Invalid Color Errors.

As a result, I put together a small VB Script to analyze the file and adjust these out-of-range colors entered by Tonto to colors that are inside the range that the CCF Compiler understands.

The following VB Script can be used to correct icon problems encountered when executing SuperNudelist on a CCF that has been Edited or Created with Tonto.

1. Create a new text file and open with notepad.
2. Paste the contents below into this file.
3. Save the file as FixTontoColors.vbs
4. Decompile your original CCF to a CSF file using CCFTools to the same folder where you saved the file in Step #3.
5. Open a command prompt in folder from Step #3
6. Enter 'cscript FixTontoColors.vbs YourCSFFileName.CSF
7. Recompile 'fixtontocolors.csf' to a CCF and use as SNL Input.

Example Execution:

SNL Input CCF named 'Lyndel.CCF'
CCFDecompile to 'Lyndel.CSF'

Run the script using command line:
cscript FixTontoColors.vbs Lyndel.CSF

Recompile the file 'fixtontocolors.csf' using CCFCompiler to a new or overwrite your existing CCF.
i.e. LyndelFixed.CCF

Use LyndelFixed for future edits under Tonto or as Input to SNL.

Whenever an 'Invalid Color' message pops up, you will need to repeat this process.

Script Begins on Next Line. Note that HTML has removed space indentation


Const ForReading = 1, ForWriting = 2, ForAppending = 3
'=================================================
' Replacement Colors 216 to 255
' These color indices were visually chosen
' from Tonto Color Palette as closest color match
' to those in System Palette Entries 216-255.
'=================================================
' Define array with 40 elements to do color translation
' used to contain remapped entries for colors 216-255
Dim arrTranslatedColors(40)


arrTranslatedColors(00)=208
arrTranslatedColors(01)=200
arrTranslatedColors(02)=164
arrTranslatedColors(03)=156
arrTranslatedColors(04)=156
arrTranslatedColors(05)=188
arrTranslatedColors(06)=151
arrTranslatedColors(07)=114
arrTranslatedColors(08)=165
arrTranslatedColors(09)=122
arrTranslatedColors(10)=122
arrTranslatedColors(11)=115
arrTranslatedColors(12)=078
arrTranslatedColors(13)=072
arrTranslatedColors(14)=072
arrTranslatedColors(15)=073
arrTranslatedColors(16)=166
arrTranslatedColors(17)=166
arrTranslatedColors(18)=123
arrTranslatedColors(19)=166
arrTranslatedColors(20)=123
arrTranslatedColors(21)=166
arrTranslatedColors(22)=123
arrTranslatedColors(23)=080
arrTranslatedColors(24)=215
arrTranslatedColors(25)=215
arrTranslatedColors(26)=172
arrTranslatedColors(27)=172
arrTranslatedColors(28)=172
arrTranslatedColors(29)=129
arrTranslatedColors(30)=129
arrTranslatedColors(31)=129
arrTranslatedColors(32)=086
arrTranslatedColors(33)=086
arrTranslatedColors(34)=086
arrTranslatedColors(35)=043
arrTranslatedColors(36)=043
arrTranslatedColors(37)=043
arrTranslatedColors(38)=000
arrTranslatedColors(39)=000

' Replace Colors
call Main

public sub Main
call WScript.Echo("===============================================================")
call WScript.Echo(" Tonto out-of-range color index adjustment script.")
call WScript.Echo("===============================================================")

set ObjArgs=WScript.Arguments

If objArgs.Count < 1 Then
call WScript.Echo("Error! Incorrect Number of command-line parameters specified.")
call WScript.Echo(" Input .CSF File must be specified.")
call WScript.Echo
call WScript.Echo("Type cscript FixTontoColors.vbs ")
call WScript.Echo("===============================================================")
Exit Sub
End If

' Use Windows Scripting Host FSO for File manipulation.
Set objFSO = CreateObject("Scripting.FileSystemObject")

' build Input filename and path.
strPath = ".\"
strInputFileName = objArgs(0)
strInputFullName = objArgs(0) 'objFSO.BuildPath(strPath, strInputFileName)
If not objFSO.FileExists(strInputFullName) Then
call wscript.echo ("Input File: " & strInputFullName & " does not exist.")
exit sub
End If

' Open Input File.
On Error Resume Next
Err.Clear
Set objInputFile = objFSO.OpenTextFile(strInputFullName, ForReading,TristateFalse)
If Err.Number <> 0 Then
call wscript.echo ("Input File: " & strInputFullName & " could not be opened for reading.")
exit sub
End If

strOutputFileName="fixtontocolors.csf"
strOutputFullName=objFSO.BuildPath(strPath,strOutputFileName)

if objFSO.FileExists(strOutputFullName) then objFSO.DeleteFile(strOutputFullName)

' Open Output File for Append as ASCII (0).
On Error Resume Next
Err.Clear
Set objOutputFile = objFSO.CreateTextFile(strOutputFullName,ForAppending,0)
If Err.Number <> 0 Then
call wscript.echo ("Output File: " & strOutputFullName & " could not be opened for writing.")
objInputFile.Close
exit sub
End If

CurrLineNum=0
ModifiedLineCount=0

'Process file line by line
Do While objInputFile.AtEndOfStream <> True
sLine = objInputFile.ReadLine
CurrLineNum=CurrLineNum+1
sModifiedLine=""
If (ProcessColorLine(sLine,sModifiedLine)=true) Then
objOutputFile.WriteLine(sModifiedLine)
modifiedLineCount=modifiedLineCount+1
'call WScript.Echo("Line Number: " & CurrLineNum & " modified.")
'call WScript.Echo(sModifiedLine)
'Exit Sub
Else
objOutputFile.WriteLine(sLine)
End If
Loop


' close files.
objInputFile.Close
objOutputFile.Close
If (modifiedLineCount > 0) Then
'On Error Goto 0
' copy output file over input file.
'call objFSO.CopyFile(strOutputFullName,strInputFullName,true)
' remove output file.
'call objFSO.DeleteFile(strOutputFileName)

call WScript.Echo("Tonto out-of-range colors detected and translated successfully.")
call WScript.Echo
call WScript.Echo("Number of CSF Lines Modified: " & ModifiedLineCount)
call WScript.Echo
call WScript.Echo("1) Please rename/copy output file """ & strOutputFileName & """")
call WScript.Echo(" to """ & strInputFileName & """.")
call WScript.Echo
call WScript.Echo("2) Recompile this file using CCFTools.")
call WScript.Echo
call WScript.Echo("3) Use the resulting CCF for future editing and as input for")
call WScript.Echo(" SuperNudelist.")
call WScript.Echo("===============================================================")
Else
call WScript.Echo("Tonto has not introduced any out-of-range colors.")
call WScript.Echo("===============================================================")
End If
End Sub




' function that returns true if any colors were modified
Public Function ProcessColorLine(sInputLine,sOutputLine)
ProcessColorLine=false
retColor1=0
retColor2=0
sOutputLine=sInputLine
If (instr(1,sInputLine,"TextColor(",1) > 0) Then

ProcessColorLine=TranslateSingleColor(sInputLine,sOutputLine)

ElseIf (instr(1,sInputLine,"BackColor(",1) > 0) Then

ProcessColorLine=TranslateSingleColor(sInputLine,sOutputLine)

ElseIf (instr(1,sInputLine,"InactiveUnselectedColor(",1) > 0) Then

ProcessColorLine=TranslateDualColor(sInputLine,sOutputLine)

ElseIf (instr(1,sInputLine,"InactiveSelectedColor(",1) > 0) Then

ProcessColorLine=TranslateDualColor(sInputLine,sOutputLine)

ElseIf (instr(1,sInputLine,"ActiveUnselectedColor(",1) > 0) Then

ProcessColorLine=TranslateDualColor(sInputLine,sOutputLine)

ElseIf (instr(1,sInputLine,"ActiveSelectedColor(",1) > 0) Then

ProcessColorLine=TranslateDualColor(sInputLine,sOutputLine)

End If
End Function

Public Function TranslateSingleColor(sInputLine,sOutputLine)
TranslateSingleColor=false

posLParen=instr(1,sInputLine,"(",1)
posRParen=instr(posLParen+1,sInputLine,")",1)
sColorValue=Mid(sInputLine,posLParen+1,posRParen-(posLParen+1))
' convert color just read to integer
iColorValue1=CInt(sColorValue)
If (iColorValue1 > 215) Then
iColorValue1=arrTranslatedColors(iColorValue1-216)
sOutputLine=Mid(sInputLine,1,posLParen) & iColorValue1 & ");"
TranslateSingleColor=true
End If
End Function

Public Function TranslateDualColor(sInputLine,sOutputLine)
bRet=false
posLParen=instr(1,sInputLine,"(",1)
posComma=instr(posLParen+1,sInputLine,",",1)
posRParen=instr(posComma+1,sInputLine,")",1)
' Get Colors Format : "XXXXXX(Color1,Color2);"
sColorValue=Mid(sInputLine,posLParen+1,posComma-(posLParen+1))
' convert color just read to integer
iColorValue1=CInt(sColorValue)

sColorValue=Mid(sInputLine,posComma+1,posRParen-(posComma+1))
' convert color just read to integer
iColorValue2=CInt(sColorValue)

TranslateDualColor=false

If (iColorValue1 > 215) Then
iColorValue1=arrTranslatedColors(iColorValue1-216)
bRet=true
End If

If (iColorValue2 > 215) Then
iColorValue2=arrTranslatedColors(iColorValue2-216)
bRet=true
End If
' if any colors translated, then build output string
If (bRet=true) then
TranslateDualColor=true
sOutputLine=Mid(sInputLine,1,posLParen) & iColorValue1 & "," & iColorValue2 & ");"
End If
End Function
Script ends on above line.

Legal Disclaimer
===================
Author resumes no responsibility for lost data resulting from use of this script.

Bump.